mirror of
https://github.com/Resxt/Plutonium-IW5-Scripts.git
synced 2025-04-19 04:32:53 +00:00
Create mapvote
This commit is contained in:
Resxt
parent
a265fd9920
commit
9749069510
148
mapvote/README.md
Normal file
148
mapvote/README.md
Normal file
@ -0,0 +1,148 @@
|
||||
# Mapvote
|
||||
|
||||
A customizable mapvote script for the multiplayer mode of Modern Warfare 3.
|
||||
|
||||
This works for both custom games and dedicated servers.
|
||||
|
||||
This is heavily inspired by [LastDemon99's IW5 mapvote](https://github.com/LastDemon99/IW5_VoteSystem).
|
||||
Huge thanks to him.
|
||||
|
||||
|
||||
*Mouse and keyboard input. Changed settings: horizontal spacing: 100*
|
||||
|
||||
|
||||
*Controller input. Custom map. Changed settings: red colors, accent mode: max*
|
||||
|
||||
## mapvote.gsc
|
||||
|
||||
### Main features
|
||||
|
||||
- It allows up to 12 elements (maps + modes) to be displayed on screen
|
||||
- You can configure how much maps and modes you want on screen
|
||||
- It will automatically adapt the amount of elements to display if you don't choose a fixed amount of maps/modes to show
|
||||
- It has separate map and mode choices
|
||||
- It supports custom DSR
|
||||
- It supports custom maps
|
||||
- It supports custom gamemode names
|
||||
- It rotates a random map from the list when there are no votes for maps. Same applies for modes too
|
||||
- Controllers are fully supported and work out of the box
|
||||
- It has a good level of customization
|
||||
- It has a debug mode to quickly preview the menu and print some values in the console
|
||||
|
||||
### Getting started
|
||||
|
||||
By default the script is disabled to avoid running on all your servers.
|
||||
Simply set `mapvote_enable` to 1 and the script will be loaded, which as a result will display the voting menu when the game ends (after the killcam).
|
||||
|
||||
To configure the menu before putting it on your server I recommend running it in a custom game with the `mapvote_debug` dvar set to `1`.
|
||||
To do that use this command in the console `set mapvote_enable 1;set mapvote_debug 1` before running a custom game.
|
||||
Start a custom game and you will see the menu.
|
||||
You can then configure the dvars directly in your console and restart the map with `map_restart` in the console to edit the menu quickly and get your perfect setup.
|
||||
|
||||
### Dvars
|
||||
|
||||
Here are the dvars you can configure:
|
||||
|
||||
| Name | Description | Default value | Accepted values |
|
||||
|---|---|---|---|
|
||||
| mapvote_enable | Toggle whether the mapvote is activated or not. 0 is off and 1 is on | 0 | 0 or 1 |
|
||||
| mapvote_debug | Toggle whether the mapvote runs in debug mode or not. This will display the mapvote menu a few seconds after starting the game. 0 is off and 1 is on | 0 | 0 or 1 |
|
||||
| mapvote_maps | A list of the maps that are available for rotation | Every maps including DLC maps and Plutonium DLC maps (excluding [Face Off maps](https://callofduty.fandom.com/wiki/Face_Off#Modern_Warfare_3)) | Any text followed by a comma (,) and then the map code name (mapname). Each block is separated with a colon (:) |
|
||||
| mapvote_modes | A list of the modes that are available for rotation. The first parameter is how the mode will be displayed, it can be set to anything you like, the second parameter is the name of the DSR file to load | "Team Deathmatch,tdm:Domination,dom" | Any text followed by a comma (,) and then the cfg name. Each block is separated with a colon (:) |
|
||||
| mapvote_additional_maps_dvars | A list of dvar name(s) that contain additional maps, respecting the `mapvote_maps` format. See [Adding a custom map](#adding-a-custom-map) | "" | Any valid dvar name that has a list of maps as value. Each dvar name is separated with a colon (:) |
|
||||
| mapvote_limits_maps | The amount of maps to display. 0 will handle it automatically | 0 | Any plain number from 0 to `mapvote_limits_max` |
|
||||
| mapvote_limits_modes | The amount of modes to display. 0 will handle it automatically | 0 | Any plain number from 0 to `mapvote_limits_max` |
|
||||
| mapvote_limits_max | The maximum amount of elements to display (maps + modes) | 12 | 2, 4, 6, 8, 10, 12 |
|
||||
| mapvote_colors_selected | The color of the text when hovered or selected. This is also the color of the votes count | blue | red, green, yellow, blue, cyan, purple, white, grey, gray, black |
|
||||
| mapvote_colors_unselected | The color of the text when not hovered and not selected | white | red, green, yellow, blue, cyan, purple, white, grey, gray, black |
|
||||
| mapvote_colors_timer | The color of the timer as long as it has more than 5 seconds remaining | blue | red, green, yellow, blue, cyan, purple, white, grey, gray, black |
|
||||
| mapvote_colors_timer_low | The color of the timer when it has 5 or less seconds remaining | red | red, green, yellow, blue, cyan, purple, white, grey, gray, black |
|
||||
| mapvote_colors_help_text | The color of the help text at the bottom explaining how to use the menu | white | red, green, yellow, blue, cyan, purple, white, grey, gray, black |
|
||||
| mapvote_colors_help_accent | The color of the accented text of the help text at the bottom | blue | red, green, yellow, blue, cyan, purple, white, grey, gray, black |
|
||||
| mapvote_colors_help_accent_mode | The accenting mode for the help text. `standard` only puts the accent color on the button to press and `max` puts it on both the buttons and the action it does | standard | standard or max |
|
||||
| mapvote_sounds_menu_enabled | Toggle whether the mapvote menu sounds are enabled or not. 0 is off and 1 is on | 1 | 0 or 1 |
|
||||
| mapvote_sounds_timer_enabled | Toggle whether the timer will start making a beeping sound every second when there's 5 or less seconds remaining to vote or not. 0 is off and 1 is on | 1 | 0 or 1 |
|
||||
| mapvote_vote_time | The time the vote lasts (in seconds) | 30 | Any plain number above 5 |
|
||||
| mapvote_blur_level | The amount of blur to put when the mapvote menu starts to show. The max recommended value is 5. 0 disables it | 2.5 | Any number |
|
||||
| mapvote_blur_fade_in_time | The time (in seconds) it takes for the blur to reach `mapvote_blur_level`. For example if you set it to 10 and `mapvote_blur_level` is 5 then it will progressively blur the screen from 0 to 5 in 10 seconds | 2 | Any number |
|
||||
| mapvote_horizontal_spacing | The horizontal spacing between the map/mode names on the left and the vote counts on the right. I recommend setting this value according to the longest map or mode name length so that it doesn't overlap with the vote counts | 75 | Any plain number |
|
||||
| mapvote_display_wait_time | Once the killcam ends, the time to wait before displaying the vote menu (in seconds) | 1 | Any number superior or equal to 0.05 |
|
||||
|
||||
### Configuration
|
||||
|
||||
Below is an example CFG showing how each dvars can be configured.
|
||||
The values you see are the default values that will be used if you don't set a dvar.
|
||||
|
||||
```c
|
||||
set mapvote_enable 1
|
||||
set mapvote_maps "Seatown,mp_seatown:Dome,mp_dome:Arkaden,mp_plaza2:Bakaara,mp_mogadishu:Resistance,mp_paris:Downturn,mp_exchange:Bootleg,mp_bootleg:Carbon,mp_carbon:Hardhat,mp_hardhat:Lockdown,mp_alpha:Village,mp_village:Fallen,mp_lambeth:Outpost,mp_radar:Interchange,mp_interchange:Underground,mp_underground:Mission,mp_bravo:Piazza,mp_italy:Liberation,mp_park:Overwatch,mp_overwatch:Black Box,mp_morningwood:Sanctuary,mp_meteora:Foundation,mp_cement:Oasis,mp_qadeem:Terminal,mp_terminal_cls:Decommission,mp_shipbreaker:Off Shore,mp_roughneck:Gulch,mp_moab:Boardwalk,mp_boardwalk:Parish,mp_nola:Favela,mp_favela:Highrise,mp_highrise:Skidrow,mp_nightshift:Nuketown,mp_nuked:Rust,mp_rust"
|
||||
set mapvote_modes "Team Deathmatch,TDM_default:Domination,DOM_default"
|
||||
set mapvote_limits_maps 0
|
||||
set mapvote_limits_modes 0
|
||||
set mapvote_limits_max 12
|
||||
set mapvote_colors_selected "blue"
|
||||
set mapvote_colors_unselected "white"
|
||||
set mapvote_colors_timer "blue"
|
||||
set mapvote_colors_timer_low "red"
|
||||
set mapvote_colors_help_text "white"
|
||||
set mapvote_colors_help_accent "blue"
|
||||
set mapvote_colors_help_accent_mode "standard"
|
||||
set mapvote_sounds_menu_enabled 1
|
||||
set mapvote_sounds_timer_enabled 1
|
||||
set mapvote_vote_time 30
|
||||
set mapvote_blur_level 2.5
|
||||
set mapvote_blur_fade_in_time 2
|
||||
set mapvote_horizontal_spacing 75
|
||||
set mapvote_display_wait_time 1
|
||||
```
|
||||
|
||||
Here are some pre-set values if you want to quickly copy/paste something
|
||||
|
||||
| Description | Value |
|
||||
|---|---|
|
||||
| All base game maps | "Seatown,mp_seatown:Dome,mp_dome:Arkaden,mp_plaza2:Bakaara,mp_mogadishu:Resistance,mp_paris:Downturn,mp_exchange:Bootleg,mp_bootleg:Carbon,mp_carbon:Hardhat,mp_hardhat:Lockdown,mp_alpha:Village,mp_village:Fallen,mp_lambeth:Outpost,mp_radar:Interchange,mp_interchange:Underground,mp_underground:Mission,mp_bravo" |
|
||||
| All DLC maps | "Piazza,mp_italy:Liberation,mp_park:Overwatch,mp_overwatch:Black Box,mp_morningwood:Sanctuary,mp_meteora:Foundation,mp_cement:Oasis,mp_qadeem:Terminal,mp_terminal_cls:Decommission,mp_shipbreaker:Off Shore,mp_roughneck:Gulch,mp_moab:Boardwalk,mp_boardwalk:Parish,mp_nola" |
|
||||
| All Face Off maps | "Lookout,mp_restrepo_ss:Getaway,mp_hillside_ss:Erosion,mp_courtyard:Aground,mp_aground_ss:Vortex,mp_six_ss:U-Turn,mp_burn_ss:Intersection,mp_crosswalk_ss" |
|
||||
| All Plutonium DLC maps | "Favela,mp_favela:Highrise,mp_highrise:Skidrow,mp_nightshift:Nuketown,mp_nuked:Rust,mp_rust" |
|
||||
| Classic modes | "Team Deathmatch,TDM_default:Domination,DOM_default" |
|
||||
| Objective modes | "Demolition,DD_default:Headquaters,HQ_default:Capture the Flag,CTF_default" |
|
||||
| Alternative modes | "Kill Confirmed,KC_default:Team Defender,TDEF_default:Sabotage,SAB_default:Drop Zone,DZ_default" |
|
||||
| Party modes | "Gun Game,GG_default:One in the Chamber,OIC_default" |
|
||||
| Juggernaut modes | "Juggernaut,JUG_default:Team Juggernaut,TJ_default" |
|
||||
| FFA 24/7 | "Free for All,FFA_default" |
|
||||
| SND 24/7 | "Search & Destroy,SD_default" |
|
||||
| Infected 24/7 | "Infected,INF_default" |
|
||||
|
||||
### Adding a custom map
|
||||
|
||||
**[IMPORTANT]** MW3 has a limit of `1024` characters for dvars so the value of `mapvote_maps` cannot be longer than that or it will fail to read it properly.
|
||||
|
||||
For this reason there are ways to add a custom map to your rotation:
|
||||
|
||||
#### Adding a custom map the classic way
|
||||
|
||||
You can simply add your map normally to `mapvote_maps` while being sure the dvar doesn't have more than `1024` characters.
|
||||
So for example, if you wanted to add Scrapyard as a custom map in your rotation `"Seatown,mp_seatown:Dome,mp_dome"` would become `"Seatown,mp_seatown:Dome,mp_dome:Scrapyard,mp_boneyard"`
|
||||
|
||||
#### Adding a custom map the advanced way
|
||||
|
||||
On the other hand, if `mapvote_maps` is close to having more than `1024` characters or if you want to better organize your custom maps you can use the system I put in place.
|
||||
|
||||
Simply create a dvar with any name you want, for example `mapvote_maps_mw2` and then add maps to it the same way you add maps to `mapvote_maps` and respecting the `1024` characters limit too.
|
||||
Finally, add the **name** of this dvar to `mapvote_additional_maps_dvars`.
|
||||
So in this example `mapvote_additional_maps_dvars "mapvote_maps_mw2"`.
|
||||
The script will then automatically read all values from `mapvote_maps` and `mapvote_maps_mw2`, all your maps will be taken into account for the randomization of available maps.
|
||||
|
||||
You can simply repeat this process to add even more dvars in case you go up to the characters limit again or if you simply want to organize your maps dvars.
|
||||
For example you could create an additional dvar named `mapvote_maps_bo2` that holds some maps and then add it to the list of dvars like this `mapvote_additional_maps_dvars "mapvote_maps_mw2:mapvote_maps_bo2"`.
|
||||
|
||||
### Notes
|
||||
|
||||
- If right click is set to toggle ads then pressing right click will make the player go up by one every 0.25s until he right clicks again.
|
||||
If I didn't change it to be that way players with toggle ads would have to press right click twice to go up by one all the time.
|
||||
Now instead they simply right click once to start going up and right click again to stop which is a better user experience.
|
||||
- When there's only one map/mode, instead of showing a single vote possibility, your single map/mode will be hidden to make the user experience better but it will still always rotate to your one map/mode
|
||||
- If some map/mode names or vote count don't display at all then you probably have other scripts that create HUD elements and there's too much elements to display so either remove your script or lower `mapvote_limits_max` so that the mapvote will have less elements to display
|
||||
- When two maps/modes have the same votes, the lowest one in the list will win. In the future it would be nice to randomize between both
|
||||
- The game doesn't seem to have a way to display the correct key for aiming (whether you use hold to ads or toggle ads) so after trying multiple solutions I decided to simply put both keys on screen. It's not perfect but this ensures the players have all the information to use the menu properly
|
||||
- Once you enable your controller the game seems to never display the keyboard key again for the `Use` key (Undo). It's a pretty situational/rare bug but it would be nice to find another key or a way to somehow fix it in the future
|
||||
BIN
mapvote/images/mapvote1.png
Normal file
BIN
mapvote/images/mapvote1.png
Normal file
Binary file not shown.
|
After Width: | Height: | Size: 3.3 MiB |
BIN
mapvote/images/mapvote2.png
Normal file
BIN
mapvote/images/mapvote2.png
Normal file
Binary file not shown.
|
After Width: | Height: | Size: 3.3 MiB |
868
mapvote/mapvote.gsc
Normal file
868
mapvote/mapvote.gsc
Normal file
@ -0,0 +1,868 @@
|
||||
/*
|
||||
======================================================================
|
||||
| Game: Plutonium IW5 |
|
||||
| Description : Let players vote |
|
||||
| for a map and mode at the end of each game |
|
||||
| Author: Resxt |
|
||||
======================================================================
|
||||
| https://github.com/Resxt/Plutonium-IW5-Scripts/tree/main/mapvote |
|
||||
======================================================================
|
||||
*/
|
||||
|
||||
#include maps\mp\gametypes\_hud_util;
|
||||
#include common_scripts\utility;
|
||||
#include maps\mp\_utility;
|
||||
|
||||
/* Entry point */
|
||||
|
||||
Init()
|
||||
{
|
||||
if (GetDvarInt("mapvote_enable"))
|
||||
{
|
||||
replaceFunc(maps\mp\gametypes\_gamelogic::waittillFinalKillcamDone, ::OnKillcamEnd);
|
||||
|
||||
InitMapvote();
|
||||
}
|
||||
}
|
||||
|
||||
|
||||
|
||||
/* Init section */
|
||||
|
||||
InitMapvote()
|
||||
{
|
||||
InitDvars();
|
||||
InitVariables();
|
||||
|
||||
if (GetDvarInt("mapvote_debug"))
|
||||
{
|
||||
Print("[MAPVOTE] Debug mode is ON");
|
||||
wait 3;
|
||||
level thread StartVote();
|
||||
level thread ListenForEndVote();
|
||||
}
|
||||
else
|
||||
{
|
||||
// Starting the mapvote normally is handled by the replaceFunc in Init()
|
||||
}
|
||||
}
|
||||
|
||||
InitDvars()
|
||||
{
|
||||
SetDvarIfNotInitialized("mapvote_debug", false);
|
||||
|
||||
SetDvarIfNotInitialized("mapvote_maps", "Seatown,mp_seatown:Dome,mp_dome:Arkaden,mp_plaza2:Bakaara,mp_mogadishu:Resistance,mp_paris:Downturn,mp_exchange:Bootleg,mp_bootleg:Carbon,mp_carbon:Hardhat,mp_hardhat:Lockdown,mp_alpha:Village,mp_village:Fallen,mp_lambeth:Outpost,mp_radar:Interchange,mp_interchange:Underground,mp_underground:Mission,mp_bravo:Piazza,mp_italy:Liberation,mp_park:Overwatch,mp_overwatch:Black Box,mp_morningwood:Sanctuary,mp_meteora:Foundation,mp_cement:Oasis,mp_qadeem:Terminal,mp_terminal_cls:Decommission,mp_shipbreaker:Off Shore,mp_roughneck:Gulch,mp_moab:Boardwalk,mp_boardwalk:Parish,mp_nola:Favela,mp_favela:Highrise,mp_highrise:Skidrow,mp_nightshift:Nuketown,mp_nuked:Rust,mp_rust");
|
||||
SetDvarIfNotInitialized("mapvote_modes", "Team Deathmatch,TDM_default:Domination,DOM_default");
|
||||
SetDvarIfNotInitialized("mapvote_additional_maps_dvars", "");
|
||||
SetDvarIfNotInitialized("mapvote_limits_maps", 0);
|
||||
SetDvarIfNotInitialized("mapvote_limits_modes", 0);
|
||||
SetDvarIfNotInitialized("mapvote_limits_max", 12);
|
||||
SetDvarIfNotInitialized("mapvote_sounds_menu_enabled", 1);
|
||||
SetDvarIfNotInitialized("mapvote_sounds_timer_enabled", 1);
|
||||
SetDvarIfNotInitialized("mapvote_colors_selected", "blue");
|
||||
SetDvarIfNotInitialized("mapvote_colors_unselected", "white");
|
||||
SetDvarIfNotInitialized("mapvote_colors_timer", "blue");
|
||||
SetDvarIfNotInitialized("mapvote_colors_timer_low", "red");
|
||||
SetDvarIfNotInitialized("mapvote_colors_help_text", "white");
|
||||
SetDvarIfNotInitialized("mapvote_colors_help_accent", "blue");
|
||||
SetDvarIfNotInitialized("mapvote_colors_help_accent_mode", "standard");
|
||||
SetDvarIfNotInitialized("mapvote_vote_time", 30);
|
||||
SetDvarIfNotInitialized("mapvote_blur_level", 2.5);
|
||||
SetDvarIfNotInitialized("mapvote_blur_fade_in_time", 2);
|
||||
SetDvarIfNotInitialized("mapvote_horizontal_spacing", 75);
|
||||
SetDvarIfNotInitialized("mapvote_display_wait_time", 1);
|
||||
}
|
||||
|
||||
InitVariables()
|
||||
{
|
||||
mapsString = GetDvar("mapvote_maps");
|
||||
|
||||
foreach (mapDvar in StrTok(GetDvar("mapvote_additional_maps_dvars"), ":"))
|
||||
{
|
||||
mapsString = mapsString + ":" + GetDvar(mapDvar);
|
||||
}
|
||||
|
||||
mapsArray = StrTok(mapsString, ":");
|
||||
voteLimits = [];
|
||||
|
||||
modesArray = StrTok(GetDvar("mapvote_modes"), ":");
|
||||
|
||||
if (GetDvarInt("mapvote_limits_maps") == 0 && GetDvarInt("mapvote_limits_modes") == 0)
|
||||
{
|
||||
voteLimits = GetVoteLimits(mapsArray.size, modesArray.size);
|
||||
}
|
||||
else if (GetDvarInt("mapvote_limits_maps") > 0 && GetDvarInt("mapvote_limits_modes") == 0)
|
||||
{
|
||||
voteLimits = GetVoteLimits(GetDvarInt("mapvote_limits_maps"), modesArray.size);
|
||||
}
|
||||
else if (GetDvarInt("mapvote_limits_maps") == 0 && GetDvarInt("mapvote_limits_modes") > 0)
|
||||
{
|
||||
voteLimits = GetVoteLimits(mapsArray.size, GetDvarInt("mapvote_limits_modes"));
|
||||
}
|
||||
else
|
||||
{
|
||||
voteLimits = GetVoteLimits(GetDvarInt("mapvote_limits_maps"), GetDvarInt("mapvote_limits_modes"));
|
||||
}
|
||||
|
||||
level.mapvote["limit"]["maps"] = voteLimits["maps"];
|
||||
level.mapvote["limit"]["modes"] = voteLimits["modes"];
|
||||
|
||||
SetMapvoteData("map", mapsArray);
|
||||
SetMapvoteData("mode");
|
||||
|
||||
level.mapvote["vote"]["maps"] = [];
|
||||
level.mapvote["vote"]["modes"] = [];
|
||||
level.mapvote["hud"]["maps"] = [];
|
||||
level.mapvote["hud"]["modes"] = [];
|
||||
}
|
||||
|
||||
|
||||
|
||||
/* Player section */
|
||||
|
||||
/*
|
||||
This is used instead of notifyonplayercommand("mapvote_up", "speed_throw")
|
||||
to fix an issue where players using toggle ads would have to press right click twice for it to register one right click.
|
||||
With this instead it keeps scrolling every 0.25s until they right click again which is a better user experience
|
||||
*/
|
||||
ListenForRightClick()
|
||||
{
|
||||
self endon("disconnect");
|
||||
|
||||
while (true)
|
||||
{
|
||||
if (self AdsButtonPressed())
|
||||
{
|
||||
self notify("mapvote_up");
|
||||
wait 0.25;
|
||||
}
|
||||
|
||||
wait 0.05;
|
||||
}
|
||||
}
|
||||
|
||||
ListenForVoteInputs()
|
||||
{
|
||||
self endon("disconnect");
|
||||
|
||||
self thread ListenForRightClick();
|
||||
|
||||
self notifyonplayercommand("mapvote_down", "+attack");
|
||||
self notifyonplayercommand("mapvote_select", "+gostand");
|
||||
self notifyonplayercommand("mapvote_unselect", "+usereload");
|
||||
self notifyonplayercommand("mapvote_unselect", "+activate");
|
||||
|
||||
while(true)
|
||||
{
|
||||
input = self waittill_any_return("mapvote_down", "mapvote_up", "mapvote_select", "mapvote_unselect");
|
||||
|
||||
section = self.mapvote["vote_section"];
|
||||
|
||||
if (section == "end" && input != "mapvote_unselect")
|
||||
{
|
||||
continue; // stop/skip execution
|
||||
}
|
||||
else if (section == "mode" && level.mapvote["modes"]["by_index"].size <= 1 && input != "mapvote_unselect")
|
||||
{
|
||||
continue; // stop/skip execution
|
||||
}
|
||||
|
||||
if (input == "mapvote_down")
|
||||
{
|
||||
if (self.mapvote[section]["hovered_index"] < (level.mapvote[section + "s"]["by_index"].size - 1))
|
||||
{
|
||||
if (GetDvarInt("mapvote_sounds_menu_enabled"))
|
||||
{
|
||||
self playlocalsound("mouse_click");
|
||||
}
|
||||
|
||||
self UpdateSelection(section, (self.mapvote[section]["hovered_index"] + 1));
|
||||
}
|
||||
}
|
||||
else if (input == "mapvote_up")
|
||||
{
|
||||
if (self.mapvote[section]["hovered_index"] > 0)
|
||||
{
|
||||
if (GetDvarInt("mapvote_sounds_menu_enabled"))
|
||||
{
|
||||
self playlocalsound("mouse_click");
|
||||
}
|
||||
|
||||
self UpdateSelection(section, (self.mapvote[section]["hovered_index"] - 1));
|
||||
}
|
||||
}
|
||||
else if (input == "mapvote_select")
|
||||
{
|
||||
if (GetDvarInt("mapvote_sounds_menu_enabled"))
|
||||
{
|
||||
self playlocalsound("mp_killconfirm_tags_pickup");
|
||||
}
|
||||
|
||||
self ConfirmSelection(section);
|
||||
}
|
||||
else if (input == "mapvote_unselect")
|
||||
{
|
||||
if (section != "map")
|
||||
{
|
||||
if (GetDvarInt("mapvote_sounds_menu_enabled"))
|
||||
{
|
||||
self playlocalsound("mine_betty_click");
|
||||
}
|
||||
|
||||
self CancelSelection(section);
|
||||
}
|
||||
}
|
||||
|
||||
wait 0.05;
|
||||
}
|
||||
}
|
||||
|
||||
|
||||
|
||||
/* Vote section */
|
||||
|
||||
CreateVoteMenu()
|
||||
{
|
||||
spacing = 20;
|
||||
hudLastPosY = 0;
|
||||
sectionsSeparation = 0;
|
||||
modesCount = 0;
|
||||
|
||||
if (level.mapvote["modes"]["by_index"].size > 1)
|
||||
{
|
||||
sectionsSeparation = 1;
|
||||
modesCount = level.mapvote["modes"]["by_index"].size;
|
||||
}
|
||||
|
||||
hudLastPosY = 0 - ((((level.mapvote["maps"]["by_index"].size + modesCount + sectionsSeparation) * spacing) / 2) - (spacing / 2));
|
||||
|
||||
for (mapIndex = 0; mapIndex < level.mapvote["maps"]["by_index"].size; mapIndex++)
|
||||
{
|
||||
mapVotesHud = CreateHudText(&"", "default", 1.5, "LEFT", "CENTER", GetDvarInt("mapvote_horizontal_spacing"), hudLastPosY, true, 0);
|
||||
mapVotesHud.color = GetGscColor(GetDvar("mapvote_colors_selected"));
|
||||
|
||||
level.mapvote["hud"]["maps"][mapIndex] = mapVotesHud;
|
||||
|
||||
foreach (player in GetHumanPlayers())
|
||||
{
|
||||
mapName = level.mapvote["maps"]["by_index"][mapIndex];
|
||||
|
||||
player.mapvote["map"][mapIndex]["hud"] = player CreateHudText(mapName, "default", 1.5, "LEFT", "CENTER", 0 - (GetDvarInt("mapvote_horizontal_spacing")), hudLastPosY);
|
||||
|
||||
if (mapIndex == 0)
|
||||
{
|
||||
player UpdateSelection("map", 0);
|
||||
}
|
||||
else
|
||||
{
|
||||
SetElementUnselected(player.mapvote["map"][mapIndex]["hud"]);
|
||||
}
|
||||
}
|
||||
|
||||
hudLastPosY += spacing;
|
||||
}
|
||||
|
||||
if (level.mapvote["modes"]["by_index"].size > 1)
|
||||
{
|
||||
hudLastPosY += spacing; // Space between maps and modes sections
|
||||
|
||||
for (modeIndex = 0; modeIndex < level.mapvote["modes"]["by_index"].size; modeIndex++)
|
||||
{
|
||||
modeVotesHud = CreateHudText(&"", "default", 1.5, "LEFT", "CENTER", GetDvarInt("mapvote_horizontal_spacing"), hudLastPosY, true, 0);
|
||||
modeVotesHud.color = GetGscColor(GetDvar("mapvote_colors_selected"));
|
||||
|
||||
level.mapvote["hud"]["modes"][modeIndex] = modeVotesHud;
|
||||
|
||||
foreach (player in GetHumanPlayers())
|
||||
{
|
||||
player.mapvote["mode"][modeIndex]["hud"] = player CreateHudText(level.mapvote["modes"]["by_index"][modeIndex], "default", 1.5, "LEFT", "CENTER", 0 - (GetDvarInt("mapvote_horizontal_spacing")), hudLastPosY);
|
||||
|
||||
SetElementUnselected(player.mapvote["mode"][modeIndex]["hud"]);
|
||||
}
|
||||
|
||||
hudLastPosY += spacing;
|
||||
}
|
||||
}
|
||||
|
||||
foreach(player in GetHumanPlayers())
|
||||
{
|
||||
player.mapvote["map"]["selected_index"] = -1;
|
||||
player.mapvote["mode"]["selected_index"] = -1;
|
||||
|
||||
buttonsHelpMessage = "";
|
||||
|
||||
if (GetDvar("mapvote_colors_help_accent_mode") == "standard")
|
||||
{
|
||||
buttonsHelpMessage = GetChatColor(GetDvar("mapvote_colors_help_text")) + "Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+attack}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to go down - Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+toggleads_throw}] OR [{+speed_throw}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to go up - Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+gostand}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to select - Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+activate}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to undo";
|
||||
}
|
||||
else if(GetDvar("mapvote_colors_help_accent_mode") == "max")
|
||||
{
|
||||
buttonsHelpMessage = GetChatColor(GetDvar("mapvote_colors_help_text")) + "Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+attack}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to go " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "down " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "- Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+toggleads_throw}] OR [{+speed_throw}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to go " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "up " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "- Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+gostand}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "select " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "- Press " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "[{+activate}] " + GetChatColor(GetDvar("mapvote_colors_help_text")) + "to " + GetChatColor(GetDvar("mapvote_colors_help_accent")) + "undo";
|
||||
}
|
||||
|
||||
player CreateHudText(buttonsHelpMessage, "default", 1.5, "CENTER", "CENTER", 0, 210);
|
||||
}
|
||||
}
|
||||
|
||||
CreateVoteTimer()
|
||||
{
|
||||
soundFX = spawn("script_origin", (0,0,0));
|
||||
soundFX hide();
|
||||
|
||||
timerhud = CreateTimer(GetDvarInt("mapvote_vote_time"), &"Vote ends in: ", "default", 1.5, "CENTER", "CENTER", 0, -210);
|
||||
timerhud.color = GetGscColor(GetDvar("mapvote_colors_timer"));
|
||||
for (i = GetDvarInt("mapvote_vote_time"); i > 0; i--)
|
||||
{
|
||||
if(i <= 5)
|
||||
{
|
||||
timerhud.color = GetGscColor(GetDvar("mapvote_colors_timer_low"));
|
||||
|
||||
if (GetDvarInt("mapvote_sounds_timer_enabled"))
|
||||
{
|
||||
soundFX playSound( "ui_mp_timer_countdown" );
|
||||
}
|
||||
}
|
||||
wait(1);
|
||||
}
|
||||
level notify("mapvote_vote_end");
|
||||
}
|
||||
|
||||
StartVote()
|
||||
{
|
||||
level endon("end_game");
|
||||
|
||||
for (i = 0; i < level.mapvote["maps"]["by_index"].size; i++)
|
||||
{
|
||||
level.mapvote["vote"]["maps"][i] = 0;
|
||||
}
|
||||
|
||||
for (i = 0; i < level.mapvote["modes"]["by_index"].size; i++)
|
||||
{
|
||||
level.mapvote["vote"]["modes"][i] = 0;
|
||||
}
|
||||
|
||||
level thread CreateVoteMenu();
|
||||
level thread CreateVoteTimer();
|
||||
|
||||
foreach (player in GetHumanPlayers())
|
||||
{
|
||||
player SetBlurForPlayer(GetDvarInt("mapvote_blur_level"), GetDvarInt("mapvote_blur_fade_in_time"));
|
||||
|
||||
player thread ListenForVoteInputs();
|
||||
}
|
||||
}
|
||||
|
||||
ListenForEndVote()
|
||||
{
|
||||
level endon("end_game");
|
||||
level waittill("mapvote_vote_end");
|
||||
|
||||
mostVotedMapIndex = 0;
|
||||
mostVotedMapVotes = 0;
|
||||
mostVotedModeIndex = 0;
|
||||
mostVotedModeVotes = 0;
|
||||
|
||||
foreach (mapIndex in GetArrayKeys(level.mapvote["vote"]["maps"]))
|
||||
{
|
||||
if (level.mapvote["vote"]["maps"][mapIndex] > mostVotedMapVotes)
|
||||
{
|
||||
mostVotedMapIndex = mapIndex;
|
||||
mostVotedMapVotes = level.mapvote["vote"]["maps"][mapIndex];
|
||||
}
|
||||
}
|
||||
|
||||
foreach (modeIndex in GetArrayKeys(level.mapvote["vote"]["modes"]))
|
||||
{
|
||||
if (level.mapvote["vote"]["modes"][modeIndex] > mostVotedModeVotes)
|
||||
{
|
||||
mostVotedModeIndex = modeIndex;
|
||||
mostVotedModeVotes = level.mapvote["vote"]["modes"][modeIndex];
|
||||
}
|
||||
}
|
||||
|
||||
if (mostVotedMapVotes == 0)
|
||||
{
|
||||
mostVotedMapIndex = GetRandomElementInArray(GetArrayKeys(level.mapvote["vote"]["maps"]));
|
||||
|
||||
if (GetDvarInt("mapvote_debug"))
|
||||
{
|
||||
Print("[MAPVOTE] No vote for map. Chosen random map index: " + mostVotedMapIndex);
|
||||
}
|
||||
}
|
||||
else
|
||||
{
|
||||
if (GetDvarInt("mapvote_debug"))
|
||||
{
|
||||
Print("[MAPVOTE] Most voted map has " + mostVotedMapVotes + " votes. Most voted map index: " + mostVotedMapIndex);
|
||||
}
|
||||
}
|
||||
|
||||
if (mostVotedModeVotes == 0)
|
||||
{
|
||||
mostVotedModeIndex = GetRandomElementInArray(GetArrayKeys(level.mapvote["vote"]["modes"]));
|
||||
|
||||
if (GetDvarInt("mapvote_debug"))
|
||||
{
|
||||
Print("[MAPVOTE] No vote for mode. Chosen random mode index: " + mostVotedModeIndex);
|
||||
}
|
||||
}
|
||||
else
|
||||
{
|
||||
if (GetDvarInt("mapvote_debug"))
|
||||
{
|
||||
Print("[MAPVOTE] Most voted mode has " + mostVotedModeVotes + " votes. Most voted mode index: " + mostVotedModeIndex);
|
||||
}
|
||||
}
|
||||
|
||||
modeName = level.mapvote["modes"]["by_index"][mostVotedModeIndex];
|
||||
modeDsr = level.mapvote["modes"]["by_name"][level.mapvote["modes"]["by_index"][mostVotedModeIndex]];
|
||||
mapName = level.mapvote["maps"]["by_name"][level.mapvote["maps"]["by_index"][mostVotedMapIndex]];
|
||||
|
||||
if (GetDvarInt("mapvote_debug"))
|
||||
{
|
||||
Print("[MAPVOTE] mapName: " + mapName);
|
||||
Print("[MAPVOTE] modeName: " + modeName);
|
||||
Print("[MAPVOTE] modeDsr: " + modeDsr);
|
||||
Print("[MAPVOTE] Rotating to " + mapName + " | " + modeName + " (" + modeDsr + ".dsr)");
|
||||
}
|
||||
|
||||
cmdexec("load_dsr " + modeDsr);
|
||||
wait(0.05);
|
||||
cmdexec("map " + mapName);
|
||||
}
|
||||
|
||||
SetMapvoteData(type, elements)
|
||||
{
|
||||
limit = level.mapvote["limit"][type + "s"];
|
||||
|
||||
availableElements = [];
|
||||
|
||||
if (IsDefined(elements))
|
||||
{
|
||||
availableElements = elements;
|
||||
}
|
||||
else
|
||||
{
|
||||
availableElements = StrTok(GetDvar("mapvote_" + type + "s"), ":");
|
||||
}
|
||||
|
||||
if (availableElements.size < limit)
|
||||
{
|
||||
limit = availableElements.size;
|
||||
}
|
||||
|
||||
if (type == "map")
|
||||
{
|
||||
finalMapElements = [];
|
||||
|
||||
foreach (mapElement in availableElements)
|
||||
{
|
||||
finalMapElement = StrTok(mapElement, ",");
|
||||
finalMapElements = AddElementToArray(finalMapElements, finalMapElement[0]);
|
||||
|
||||
level.mapvote["maps"]["by_name"][finalMapElement[0]] = finalMapElement[1];
|
||||
}
|
||||
|
||||
level.mapvote["maps"]["by_index"] = GetRandomUniqueElementsInArray(finalMapElements, limit);
|
||||
}
|
||||
else if (type == "mode")
|
||||
{
|
||||
finalElements = [];
|
||||
|
||||
foreach (mode in GetRandomUniqueElementsInArray(availableElements, limit))
|
||||
{
|
||||
splittedMode = StrTok(mode, ",");
|
||||
finalElements = AddElementToArray(finalElements, splittedMode[0]);
|
||||
|
||||
level.mapvote["modes"]["by_name"][splittedMode[0]] = splittedMode[1];
|
||||
}
|
||||
|
||||
level.mapvote["modes"]["by_index"] = finalElements;
|
||||
}
|
||||
}
|
||||
|
||||
/*
|
||||
Gets the amount of maps and modes to display on screen
|
||||
This is used to get default values if the limits dvars are not set
|
||||
It will dynamically adjust the amount of maps and modes to show
|
||||
*/
|
||||
GetVoteLimits(mapsAmount, modesAmount)
|
||||
{
|
||||
maxLimit = GetDvarInt("mapvote_limits_max");
|
||||
limits = [];
|
||||
|
||||
if (!IsDefined(modesAmount))
|
||||
{
|
||||
if (mapsAmount <= maxLimit)
|
||||
{
|
||||
return mapsAmount;
|
||||
}
|
||||
else
|
||||
{
|
||||
return maxLimit;
|
||||
}
|
||||
}
|
||||
|
||||
if ((mapsAmount + modesAmount) <= maxLimit)
|
||||
{
|
||||
limits["maps"] = mapsAmount;
|
||||
limits["modes"] = modesAmount;
|
||||
}
|
||||
else
|
||||
{
|
||||
if (mapsAmount >= (maxLimit / 2) && modesAmount >= (maxLimit))
|
||||
{
|
||||
limits["maps"] = (maxLimit / 2);
|
||||
limits["modes"] = (maxLimit / 2);
|
||||
}
|
||||
else
|
||||
{
|
||||
if (mapsAmount > (maxLimit / 2))
|
||||
{
|
||||
finalMapsAmount = 0;
|
||||
|
||||
if (modesAmount <= 1)
|
||||
{
|
||||
limits["maps"] = maxLimit;
|
||||
}
|
||||
else
|
||||
{
|
||||
limits["maps"] = (maxLimit - modesAmount);
|
||||
}
|
||||
|
||||
limits["modes"] = modesAmount;
|
||||
}
|
||||
else if (modesAmount > (maxLimit / 2))
|
||||
{
|
||||
limits["maps"] = mapsAmount;
|
||||
limits["modes"] = (maxLimit - mapsAmount);
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
return limits;
|
||||
}
|
||||
|
||||
OnKillcamEnd()
|
||||
{
|
||||
if (!IsDefined(level.finalkillcam_winner))
|
||||
{
|
||||
if (isRoundBased() && !wasLastRound())
|
||||
return false;
|
||||
wait GetDvarInt("mapvote_display_wait_time");
|
||||
|
||||
StartVote();
|
||||
ListenForEndVote();
|
||||
return false;
|
||||
}
|
||||
|
||||
level waittill("final_killcam_done");
|
||||
if (isRoundBased() && !wasLastRound())
|
||||
return true;
|
||||
wait GetDvarInt("mapvote_display_wait_time");
|
||||
|
||||
StartVote();
|
||||
ListenForEndVote();
|
||||
return true;
|
||||
}
|
||||
|
||||
|
||||
|
||||
/* HUD section */
|
||||
|
||||
UpdateSelection(type, index)
|
||||
{
|
||||
if (type == "map" || type == "mode")
|
||||
{
|
||||
if (!IsDefined(self.mapvote[type]["hovered_index"]))
|
||||
{
|
||||
self.mapvote[type]["hovered_index"] = 0;
|
||||
}
|
||||
|
||||
self.mapvote["vote_section"] = type;
|
||||
|
||||
if (IsDefined(self.mapvote[type][self.mapvote[type]["hovered_index"]]))
|
||||
{
|
||||
SetElementUnselected(self.mapvote[type][self.mapvote[type]["hovered_index"]]["hud"]); // Unselect previous element
|
||||
}
|
||||
|
||||
if (IsDefined(self.mapvote[type][index]))
|
||||
{
|
||||
SetElementSelected(self.mapvote[type][index]["hud"]); // Select new element
|
||||
}
|
||||
|
||||
self.mapvote[type]["hovered_index"] = index; // Update the index
|
||||
}
|
||||
else if (type == "end")
|
||||
{
|
||||
self.mapvote["vote_section"] = "end";
|
||||
}
|
||||
}
|
||||
|
||||
ConfirmSelection(type)
|
||||
{
|
||||
self.mapvote[type]["selected_index"] = self.mapvote[type]["hovered_index"];
|
||||
level.mapvote["vote"][type + "s"][self.mapvote[type]["selected_index"]] = (level.mapvote["vote"][type + "s"][self.mapvote[type]["selected_index"]] + 1);
|
||||
level.mapvote["hud"][type + "s"][self.mapvote[type]["selected_index"]] SetValue(level.mapvote["vote"][type + "s"][self.mapvote[type]["selected_index"]]);
|
||||
|
||||
if (type == "map")
|
||||
{
|
||||
modeIndex = 0;
|
||||
|
||||
if (IsDefined(self.mapvote["mode"]["hovered_index"]))
|
||||
{
|
||||
modeIndex = self.mapvote["mode"]["hovered_index"];
|
||||
}
|
||||
|
||||
self UpdateSelection("mode", modeIndex);
|
||||
}
|
||||
else if (type == "mode")
|
||||
{
|
||||
self UpdateSelection("end");
|
||||
}
|
||||
}
|
||||
|
||||
CancelSelection(type)
|
||||
{
|
||||
typeToCancel = "";
|
||||
|
||||
if (type == "mode")
|
||||
{
|
||||
typeToCancel = "map";
|
||||
}
|
||||
else if (type == "end")
|
||||
{
|
||||
typeToCancel = "mode";
|
||||
}
|
||||
|
||||
level.mapvote["vote"][typeToCancel + "s"][self.mapvote[typeToCancel]["selected_index"]] = (level.mapvote["vote"][typeToCancel + "s"][self.mapvote[typeToCancel]["selected_index"]] - 1);
|
||||
level.mapvote["hud"][typeToCancel + "s"][self.mapvote[typeToCancel]["selected_index"]] SetValue(level.mapvote["vote"][typeToCancel + "s"][self.mapvote[typeToCancel]["selected_index"]]);
|
||||
|
||||
self.mapvote[typeToCancel]["selected_index"] = -1;
|
||||
|
||||
if (type == "mode")
|
||||
{
|
||||
if (IsDefined(self.mapvote["mode"][self.mapvote["mode"]["hovered_index"]]))
|
||||
{
|
||||
SetElementUnselected(self.mapvote["mode"][self.mapvote["mode"]["hovered_index"]]["hud"]);
|
||||
}
|
||||
|
||||
self.mapvote["vote_section"] = "map";
|
||||
}
|
||||
else if (type == "end")
|
||||
{
|
||||
self.mapvote["vote_section"] = "mode";
|
||||
}
|
||||
}
|
||||
|
||||
SetElementSelected(element)
|
||||
{
|
||||
element.color = GetGscColor(GetDvar("mapvote_colors_selected"));
|
||||
}
|
||||
|
||||
SetElementUnselected(element)
|
||||
{
|
||||
element.color = GetGscColor(GetDvar("mapvote_colors_unselected"));
|
||||
}
|
||||
|
||||
CreateHudText(text, font, fontScale, relativeToX, relativeToY, relativeX, relativeY, isServer, value)
|
||||
{
|
||||
hudText = "";
|
||||
|
||||
if (IsDefined(isServer) && isServer)
|
||||
{
|
||||
hudText = CreateServerFontString( font, fontScale );
|
||||
}
|
||||
else
|
||||
{
|
||||
hudText = CreateFontString( font, fontScale );
|
||||
}
|
||||
|
||||
if (IsDefined(value))
|
||||
{
|
||||
hudText.label = text;
|
||||
hudText SetValue(value);
|
||||
}
|
||||
else
|
||||
{
|
||||
hudText SetText(text);
|
||||
}
|
||||
|
||||
hudText SetPoint(relativeToX, relativeToY, relativeX, relativeY);
|
||||
|
||||
hudText.hideWhenInMenu = 1;
|
||||
hudText.glowAlpha = 0;
|
||||
|
||||
return hudText;
|
||||
}
|
||||
|
||||
CreateTimer(time, label, font, fontScale, relativeToX, relativeToY, relativeX, relativeY)
|
||||
{
|
||||
timer = createServerTimer(font, fontScale);
|
||||
timer setpoint(relativeToX, relativeToY, relativeX, relativeY);
|
||||
timer.label = label;
|
||||
timer.hideWhenInMenu = 1;
|
||||
timer.glowAlpha = 0;
|
||||
timer setTimer(time);
|
||||
|
||||
return timer;
|
||||
}
|
||||
|
||||
|
||||
|
||||
/* Utils section */
|
||||
|
||||
SetDvarIfNotInitialized(dvar, value)
|
||||
{
|
||||
if (!IsInitialized(dvar))
|
||||
{
|
||||
SetDvar(dvar, value);
|
||||
}
|
||||
}
|
||||
|
||||
IsInitialized(dvar)
|
||||
{
|
||||
result = GetDvar(dvar);
|
||||
return result != "";
|
||||
}
|
||||
|
||||
IsBot()
|
||||
{
|
||||
return IsDefined(self.pers["isBot"]) && self.pers["isBot"];
|
||||
}
|
||||
|
||||
GetHumanPlayers()
|
||||
{
|
||||
humanPlayers = [];
|
||||
|
||||
foreach (player in level.players)
|
||||
{
|
||||
if (!player IsBot())
|
||||
{
|
||||
humanPlayers = AddElementToArray(humanPlayers, player);
|
||||
}
|
||||
}
|
||||
|
||||
return humanPlayers;
|
||||
}
|
||||
|
||||
GetRandomElementInArray(array)
|
||||
{
|
||||
return array[GetArrayKeys(array)[randomint(array.size)]];
|
||||
}
|
||||
|
||||
GetRandomUniqueElementsInArray(array, limit)
|
||||
{
|
||||
finalElements = [];
|
||||
|
||||
for (i = 0; i < limit; i++)
|
||||
{
|
||||
findElement = true;
|
||||
|
||||
while (findElement)
|
||||
{
|
||||
randomElement = GetRandomElementInArray(array);
|
||||
|
||||
if (!ArrayContainsValue(finalElements, randomElement))
|
||||
{
|
||||
finalElements = AddElementToArray(finalElements, randomElement);
|
||||
|
||||
findElement = false;
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
return finalElements;
|
||||
}
|
||||
|
||||
ArrayContainsValue(array, valueToFind)
|
||||
{
|
||||
if (array.size == 0)
|
||||
{
|
||||
return false;
|
||||
}
|
||||
|
||||
foreach (value in array)
|
||||
{
|
||||
if (value == valueToFind)
|
||||
{
|
||||
return true;
|
||||
}
|
||||
}
|
||||
|
||||
return false;
|
||||
}
|
||||
|
||||
AddElementToArray(array, element)
|
||||
{
|
||||
array[array.size] = element;
|
||||
return array;
|
||||
}
|
||||
|
||||
GetGscColor(colorName)
|
||||
{
|
||||
switch (colorName)
|
||||
{
|
||||
case "red":
|
||||
return (1, 0, 0.059);
|
||||
|
||||
case "green":
|
||||
return (0.549, 0.882, 0.043);
|
||||
|
||||
case "yellow":
|
||||
return (1, 0.725, 0);
|
||||
|
||||
case "blue":
|
||||
return (0, 0.553, 0.973);
|
||||
|
||||
case "cyan":
|
||||
return (0, 0.847, 0.922);
|
||||
|
||||
case "purple":
|
||||
return (0.427, 0.263, 0.651);
|
||||
|
||||
case "white":
|
||||
return (1, 1, 1);
|
||||
|
||||
case "grey":
|
||||
case "gray":
|
||||
return (0.137, 0.137, 0.137);
|
||||
|
||||
case "black":
|
||||
return (0, 0, 0);
|
||||
}
|
||||
}
|
||||
|
||||
GetChatColor(colorName)
|
||||
{
|
||||
switch(colorName)
|
||||
{
|
||||
case "red":
|
||||
return "^1";
|
||||
|
||||
case "green":
|
||||
return "^2";
|
||||
|
||||
case "yellow":
|
||||
return "^3";
|
||||
|
||||
case "blue":
|
||||
return "^4";
|
||||
|
||||
case "cyan":
|
||||
return "^5";
|
||||
|
||||
case "purple":
|
||||
return "^6";
|
||||
|
||||
case "white":
|
||||
return "^7";
|
||||
|
||||
case "grey":
|
||||
case "gray":
|
||||
return "^0";
|
||||
|
||||
case "black":
|
||||
return "^0";
|
||||
}
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user