* data/c.m4 (b4_yydestruct_generate, b4_symbol_actions): New.

* data/yacc.c: Rename yychar1 as yytoken, as in glr.c.
Don't work on yychar (i.e., do set it to YYEMPTY, don't match
it against YYEMPTY and so forth), work on yytoken (i.e., set
it to YYEMPTY etc.).
(yydestruct): Replace with a b4_yydestruct_generate invocation.
(b4_symbol_actions): Remove.
* data/glr.c (YYTRANSLATE): As for yacc.c, if negative, it stands
for 0, end-of-input.

data/c.m4

@@ -320,3 +320,50 @@ m4_define([b4_c_arg],
 m4_define([b4_syncline],
 [m4_if(b4_synclines_flag, 1,
        [[#]line $1 $2])])
+
+
+# b4_symbol_actions(FILENAME, LINENO,
+#                   SYMBOL-TAG, SYMBOL-NUM,
+#                   SYMBOL-ACTION, SYMBOL-TYPENAME)
+# -------------------------------------------------
+m4_define([b4_symbol_actions],
+[m4_pushdef([b4_dollar_dollar], [yyvalue.$6])dnl
+m4_pushdef([b4_at_dollar], [yylocation])dnl
+      case $4: /* $3 */
+b4_syncline([$2], [$1])
+        $5;
+b4_syncline([@oline@], [@ofile@])
+        break;
+m4_popdef([b4_at_dollar])dnl
+m4_popdef([b4_dollar_dollar])dnl
+])
+
+
+# b4_yydestruct_generate(FUNTION-DECLARATOR)
+# ------------------------------------------
+# Generate the "yydestruct" function, which declaration is issued using
+# FUNTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
+# or "b4_c_function_def" for K&R.
+m4_define([b4_yydestruct_generate],
+[[/*-----------------------------------------------.
+| Release the memory associated to this symbol.  |
+`-----------------------------------------------*/
+
+]$1([yydestruct],
+    [static void],
+    [[int yytype],         [yytype]],
+    [[YYSTYPE yyvalue],    [yyvalue]]b4_location_if([,
+    [[YYLTYPE yylocation], [yylocation]]]))[
+{
+  /* Pacify ``unused variable'' warnings.  */
+  (void) yyvalue;
+]b4_location_if([  (void) yylocation;
+])[
+  switch (yytype)
+    {
+]m4_map([b4_symbol_actions], m4_defn([b4_symbol_destructors]))[
+      default:
+        break;
+    }
+}]dnl
+])