mirror of
https://git.savannah.gnu.org/git/bison.git
synced 2026-03-09 20:33:03 +00:00
08af01c2fc
unreliable -- especially when they're hidden inside another macro. * data/bison.m4, data/c++-skel.m4, data/c++.m4, data/c-skel.m4, data/c.m4: Remove m4_divert(-1). * data/glr.c, data/glr.cc, data/lalr1.cc, data/location.cc, data/push.c, data/yacc.c: Likewise, and replace m4_divert(0) with m4_divert_push(0) and m4_divert_pop(0). * data/output.c (output_skeleton): Don't add an m4_divert_push(0) and an m4_wrap([m4_divert_pop(0)]) to the M4. Diversion -1, which is pushed and popped by m4sugar, should be first on the stack. Provide warn, complain, and fatal function callbacks to the skeletons. This provides more flexibility than m4_fatal, improves the error message format, and captures messages for translation. Discussed starting at <http://lists.gnu.org/archive/html/bison-patches/2006-12/msg00063.html>. * data/bison.m4 (b4_error): New, invoked by... (b4_warn, b4_complain, b4_fatal): ... these new macros to wrap the skeleton scanner's new @warn(...@), @complain(...@), and @fatal(...@) directives. Because these M4 macros might be called when the current diversion is -1 or 0, m4_divert_push and m4_divert_pop is used; thus the previous removal of uses of m4_divert, which caused trouble. (b4_check_percent_code_qualifiers): Use b4_complain instead of m4_fatal to report unrecognized %code qualifiers. * data/c++-skel.m4: Use b4_complain instead of m4_fatal to report C++ push parser requests. * data/glr.c: Use b4_complain instead of m4_fatal to report non-deterministic push parser requests. Update @output usage to @output(...@) form. * data/glr.cc, data/lalr1.cc: Use b4_fatal instead of m4_fatal to report missing %defines. Update @output usage to @output(...@) form. * data/location.cc, data/push.c, data/yacc.c: Update @output usage to @output(...@) form. * src/main.c (main): Invoke skel_scanner_free. * src/scan-skel.h (skel_scanner_free): Prototype new function. * src/scan-skel.l (FLEX_NO_OBSTACK): Don't define; we now need the obstack_for_string from flex-scanner.h. (YY_DECL): Use to declare skel_lex static. (decode_at_digraphs): Remove; now handled in the new SC_AT_DIRECTIVE_ARG start condition. (fail_for_at_directive_too_many_args, fail_for_invalid_at): New static functions. (at_directive_name, AT_DIRECTIVE_ARGC_MAX, at_directive_argc, at_directive_argv): New static globals. (INITIAL): Use fail_for_invalid_at. Don't parse `@output file_name\n' or `@basename(...@)'. Instead, recognize the start of a generalized `@directive(...@)' form and start... (SC_AT_DIRECTIVE_ARG): ... this new start condition to parse the directive args (using the new obstack_for_string), to decode the contained @ diagraphs, and to perform the directive. It recognizes @basename(...@), @warn(...@), @complain(...@), @fatal(...@), and @output(...@). (SC_AT_DIRECTIVE_SKIP_WS): New start condition started by SC_AT_DIRECTIVE_ARG to skip whitespace after the argument delimiter, `@,'. (scan_skel): Initialize obstack_for_string on the first call. (skel_scanner_free): New function to free obstack_for_string. * tests/input.at (Reject bad %code qualifiers): Update test output.
296 lines
10 KiB
Plaintext
296 lines
10 KiB
Plaintext
-*- Autoconf -*-
|
|
|
|
# Language-independent M4 Macros for Bison.
|
|
# Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
|
|
|
|
# This program is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 2 of the License, or
|
|
# (at your option) any later version.
|
|
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program; if not, write to the Free Software
|
|
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
|
|
# 02110-1301 USA
|
|
|
|
|
|
## ---------------- ##
|
|
## Identification. ##
|
|
## ---------------- ##
|
|
|
|
# b4_copyright(TITLE, YEARS)
|
|
# --------------------------
|
|
m4_define([b4_copyright],
|
|
[b4_comment([A Bison parser, made by GNU Bison b4_version.])
|
|
|
|
b4_comment([$1
|
|
|
|
m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [ ])
|
|
|
|
This program is free software; you can redistribute it and/or modify
|
|
it under the terms of the GNU General Public License as published by
|
|
the Free Software Foundation; either version 2, or (at your option)
|
|
any later version.
|
|
|
|
This program is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
GNU General Public License for more details.
|
|
|
|
You should have received a copy of the GNU General Public License
|
|
along with this program; if not, write to the Free Software
|
|
Foundation, Inc., 51 Franklin Street, Fifth Floor,
|
|
Boston, MA 02110-1301, USA.])
|
|
|
|
b4_comment([As a special exception, you may create a larger work that contains
|
|
part or all of the Bison parser skeleton and distribute that work
|
|
under terms of your choice, so long as that work isn't itself a
|
|
parser generator using the skeleton or a modified version thereof
|
|
as a parser skeleton. Alternatively, if you modify or redistribute
|
|
the parser skeleton itself, you may (at your option) remove this
|
|
special exception, which will cause the skeleton and the resulting
|
|
Bison output files to be licensed under the GNU General Public
|
|
License without this special exception.
|
|
|
|
This special exception was added by the Free Software Foundation in
|
|
version 2.2 of Bison.])])
|
|
|
|
|
|
## ---------------- ##
|
|
## Error handling. ##
|
|
## ---------------- ##
|
|
|
|
# b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
|
|
# ---------------------------------------------------------------
|
|
# Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
|
|
m4_define([b4_error],
|
|
[m4_divert_push(0)[@]$1[(]$2[]m4_if([$#], [2], [],
|
|
[m4_foreach([b4_arg],
|
|
m4_dquote(m4_shift(m4_shift($@))),
|
|
[[@,]b4_arg])])[@)]m4_divert_pop(0)])
|
|
|
|
# b4_warn(FORMAT, [ARG1], [ARG2], ...)
|
|
# --------------------------------------------------------
|
|
# Write @warn(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
|
|
#
|
|
# As a simple test suite, this:
|
|
#
|
|
# m4_define([asdf], [ASDF])
|
|
# m4_define([fsa], [FSA])
|
|
# m4_define([fdsa], [FDSA])
|
|
# b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
|
|
# m4_divert(0)
|
|
# b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
|
|
# m4_divert(0)
|
|
# b4_warn([asdf), asdf], [fsa), fsa], [fdsa), fdsa])
|
|
# m4_divert(0)
|
|
# b4_warn
|
|
# m4_divert(0)
|
|
# b4_warn()
|
|
# m4_divert(0)
|
|
# b4_warn(1)
|
|
# m4_divert(0)
|
|
# b4_warn(1, 2)
|
|
#
|
|
# Should produce this:
|
|
#
|
|
# @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
|
|
# @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
|
|
# @warn(ASDF), ASDF@,FSA), FSA@,FDSA), FDSA@)
|
|
# @warn(@)
|
|
# @warn(@)
|
|
# @warn(1@)
|
|
# @warn(1@,2@)
|
|
m4_define([b4_warn],
|
|
[b4_error([[warn]], $@)])
|
|
|
|
# b4_complain(FORMAT, [ARG1], [ARG2], ...)
|
|
# ------------------------------------------------------------
|
|
# Write @complain(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
|
|
#
|
|
# See the test suite for b4_warn above.
|
|
m4_define([b4_complain],
|
|
[b4_error([[complain]], $@)])
|
|
|
|
# b4_fatal(FORMAT, [ARG1], [ARG2], ...)
|
|
# ---------------------------------------------------------
|
|
# Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
|
|
#
|
|
# See the test suite for b4_warn above.
|
|
m4_define([b4_fatal],
|
|
[b4_error([[fatal]], $@)])
|
|
|
|
|
|
## ---------------- ##
|
|
## Default values. ##
|
|
## ---------------- ##
|
|
|
|
# m4_define_default([b4_lex_param], []) dnl breaks other skeletons
|
|
m4_define_default([b4_epilogue], [])
|
|
m4_define_default([b4_parse_param], [])
|
|
|
|
# The initial column and line.
|
|
m4_define_default([b4_location_initial_column], [1])
|
|
m4_define_default([b4_location_initial_line], [1])
|
|
|
|
|
|
## ------------ ##
|
|
## Data Types. ##
|
|
## ------------ ##
|
|
|
|
# b4_ints_in(INT1, INT2, LOW, HIGH)
|
|
# ---------------------------------
|
|
# Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
|
|
m4_define([b4_ints_in],
|
|
[m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
|
|
|
|
|
|
|
|
## ------------------ ##
|
|
## Decoding options. ##
|
|
## ------------------ ##
|
|
|
|
# b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
|
|
# -----------------------------------
|
|
# Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
|
|
m4_define([b4_flag_if],
|
|
[m4_case(b4_$1_flag,
|
|
[0], [$3],
|
|
[1], [$2],
|
|
[m4_fatal([invalid $1 value: ]$1)])])
|
|
|
|
|
|
# b4_define_flag_if(FLAG)
|
|
# -----------------------
|
|
# Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
|
|
# value of the Boolean FLAG.
|
|
m4_define([b4_define_flag_if],
|
|
[_b4_define_flag_if($[1], $[2], [$1])])
|
|
|
|
# _b4_define_flag_if($1, $2, FLAG)
|
|
# --------------------------------
|
|
# This macro works around the impossibility to define macros
|
|
# inside macros, because issuing `[$1]' is not possible in M4 :(.
|
|
# This sucks hard, GNU M4 should really provide M5 like $$1.
|
|
m4_define([_b4_define_flag_if],
|
|
[m4_if([$1$2], $[1]$[2], [],
|
|
[m4_fatal([$0: Invalid arguments: $@])])dnl
|
|
m4_define([b4_$3_if],
|
|
[b4_flag_if([$3], [$1], [$2])])])
|
|
|
|
|
|
# b4_FLAG_if(IF-TRUE, IF-FALSE)
|
|
# -----------------------------
|
|
# Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
|
|
b4_define_flag_if([defines]) # Whether headers are requested.
|
|
b4_define_flag_if([error_verbose]) # Whether error are verbose.
|
|
b4_define_flag_if([glr]) # Whether a GLR parser is requested.
|
|
b4_define_flag_if([locations]) # Whether locations are tracked.
|
|
b4_define_flag_if([nondeterministic]) # Whether conflicts should be handled.
|
|
b4_define_flag_if([pull]) # Whether pull parsing is requested.
|
|
b4_define_flag_if([pure]) # Whether the interface is pure.
|
|
b4_define_flag_if([push]) # Whether push parsing is requested.
|
|
b4_define_flag_if([use_push_for_pull]) # Whether push parsing should be used
|
|
# in place of pull parsing (where
|
|
# available) for the sake of the test
|
|
# suite.
|
|
b4_define_flag_if([yacc]) # Whether POSIX Yacc is emulated.
|
|
|
|
|
|
## ------------------------- ##
|
|
## Assigning token numbers. ##
|
|
## ------------------------- ##
|
|
|
|
|
|
## ----------- ##
|
|
## Synclines. ##
|
|
## ----------- ##
|
|
|
|
# b4_basename(NAME)
|
|
# -----------------
|
|
# Similar to POSIX basename; the differences don't matter here.
|
|
# Beware that NAME is not evaluated.
|
|
m4_define([b4_basename],
|
|
[m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
|
|
|
|
|
|
# b4_syncline(LINE, FILE)
|
|
# -----------------------
|
|
m4_define([b4_syncline],
|
|
[b4_flag_if([synclines], [
|
|
b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
|
|
b4_sync_start([$1], [$2])])])
|
|
|
|
m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
|
|
m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
|
|
|
|
# b4_user_code(USER-CODE)
|
|
# -----------------------
|
|
# Emit code from the user, ending it with synclines.
|
|
m4_define([b4_user_code],
|
|
[$1
|
|
b4_syncline([@oline@], [@ofile@])])
|
|
|
|
|
|
# b4_define_user_code(MACRO)
|
|
# --------------------------
|
|
# From b4_MACRO, build b4_user_MACRO that includes the synclines.
|
|
m4_define([b4_define_user_code],
|
|
[m4_define([b4_user_$1],
|
|
[b4_user_code([b4_$1])])])
|
|
|
|
|
|
# b4_user_actions
|
|
# b4_user_initial_action
|
|
# b4_user_post_prologue
|
|
# b4_user_pre_prologue
|
|
# b4_user_stype
|
|
# ----------------------
|
|
# Macros that issue user code, ending with synclines.
|
|
b4_define_user_code([actions])
|
|
b4_define_user_code([initial_action])
|
|
b4_define_user_code([post_prologue])
|
|
b4_define_user_code([pre_prologue])
|
|
b4_define_user_code([stype])
|
|
|
|
# b4_check_percent_code_qualifiers([VAILD_QUALIFIER], [VALID_QUALIFIER], ...)
|
|
# ---------------------------------------------------------------------------
|
|
# Complain if any %code qualifier used in the grammar is not a valid qualifier.
|
|
#
|
|
# b4_used_percent_code_qualifiers must expand to a comma-delimited list of the
|
|
# %code qualifiers used in the grammar. The list as a whole must be quoted,
|
|
# but individual qualifiers in it must not be. Qualifiers will not be
|
|
# M4-expanded. Whitespace will not be stripped from the qualifiers. Any
|
|
# qualifier that is the empty string will be correctly parsed as such. If
|
|
# b4_used_percent_code_qualifiers expands to the empty string, then the list
|
|
# contains one qualifier that is the empty string. If
|
|
# b4_used_percent_code_qualifiers is undefined, then the list contains no
|
|
# qualifiers. Multiple occurrences of the same qualifier are fine.
|
|
#
|
|
# Each VALID_QUALIFIER will be M4-expanded once to define a valid qualifier. A
|
|
# VALID_QUALIFIER that expands to the empty string will correctly define the
|
|
# empty string as a valid qualifier. If b4_used_percent_code_qualifiers is
|
|
# invoked with empty parens, then there is one valid qualifier and it is the
|
|
# empty string. To specify that there are no valid qualifiers, invoke
|
|
# b4_check_percent_code_qualifiers without parens. Multiple occurrences of the
|
|
# same valid qualifier are fine.
|
|
#
|
|
# Qualifiers and valid qualifiers must not contain the characters `,' or `&'.
|
|
m4_define([b4_check_percent_code_qualifiers],
|
|
[m4_ifdef([b4_used_percent_code_qualifiers], [
|
|
m4_foreach([b4_qualifier],
|
|
m4_dquote(m4_substr(m4_split(m4_translit(m4_dquote([,]b4_used_percent_code_qualifiers), [,], [&]), [[&]]), 4)),
|
|
[m4_if(m4_index(m4_if($#, 0, [], [[,]m4_quote($*)[,]]),
|
|
[,]m4_defn([b4_qualifier])[,]),
|
|
[-1],
|
|
[b4_complain([[`%s' is not a recognized %%code qualifier]],
|
|
[m4_defn([b4_qualifier])])
|
|
])
|
|
])
|
|
])])
|