mirror of
https://git.savannah.gnu.org/git/bison.git
synced 2026-03-09 12:23:04 +00:00
4e19ab9fcd
Currently when --defines is used, we generate a header, and paste an exact copy of it into the generated parser implementation file. Let's provide a means to #include it instead. We don't do it by default because of the Autotools' ylwrap. This program wraps invocations of yacc (that uses a fixed output name: y.tab.c, y.tab.h, y.output) to support a more modern naming scheme (dir/foo.y -> dir/foo.tab.c, dir/foo.tab.h, etc.). It does that by renaming the generated files, and then by running sed to propagate these renamings inside the files themselves. Unfortunately Automake's Makefiles uses Bison as if it were Yacc (with --yacc or with -o y.tab.c) and invoke bison via ylwrap. As a consequence, as far as Bison is concerned, the output files are y.tab.c and y.tab.h, so it emits '#include "y.tab.h"'. So far, so good. But now ylwrap processes this '#include "y.tab.h"' into '#include "dir/foo.tab.h"', which is not guaranteed to always work. So, let's do the Right Thing when the output file is not y.tab.c, in which case the user should %define api.header.include. Binding this behavior to --yacc is tempting, but we recently told people to stop using --yacc (as it also enables the Yacc warnings), but rather to use -o y.tab.c. Yacc.c is the only skeleton concerned: all the others do include their header. * data/skeletons/yacc.c (b4_header_include_if): New. (api.header.include): Provide a default value when the output is not y.tab.c. * src/parse-gram.y (api.header.include): Define.
94 lines
1.6 KiB
Plaintext
94 lines
1.6 KiB
Plaintext
%code top {
|
|
#include <ctype.h> /* isdigit. */
|
|
#include <stdio.h> /* For printf, etc. */
|
|
#include <string.h> /* strcmp. */
|
|
|
|
int yylex (void);
|
|
void yyerror (char const *);
|
|
}
|
|
|
|
%define api.header.include {"calc.h"}
|
|
%define api.value.type union /* Generate YYSTYPE from these types: */
|
|
%token <double> NUM "number"
|
|
%type <double> expr term fact
|
|
|
|
/* Generate the parser description file. */
|
|
%verbose
|
|
/* Enable run-time traces (yydebug). */
|
|
%define parse.trace
|
|
|
|
/* Formatting semantic values. */
|
|
%printer { fprintf (yyo, "%g", $$); } <double>;
|
|
|
|
%% /* The grammar follows. */
|
|
input:
|
|
%empty
|
|
| input line
|
|
;
|
|
|
|
line:
|
|
'\n'
|
|
| expr '\n' { printf ("%.10g\n", $1); }
|
|
| error '\n' { yyerrok; }
|
|
;
|
|
|
|
expr:
|
|
expr '+' term { $$ = $1 + $3; }
|
|
| expr '-' term { $$ = $1 - $3; }
|
|
| term
|
|
;
|
|
|
|
term:
|
|
term '*' fact { $$ = $1 * $3; }
|
|
| term '/' fact { $$ = $1 / $3; }
|
|
| fact
|
|
;
|
|
|
|
fact:
|
|
"number"
|
|
| '(' expr ')' { $$ = $2; }
|
|
;
|
|
|
|
%%
|
|
|
|
int
|
|
yylex (void)
|
|
{
|
|
int c;
|
|
|
|
/* Ignore white space, get first nonwhite character. */
|
|
while ((c = getchar ()) == ' ' || c == '\t')
|
|
continue;
|
|
|
|
if (c == EOF)
|
|
return 0;
|
|
|
|
/* Char starts a number => parse the number. */
|
|
if (c == '.' || isdigit (c))
|
|
{
|
|
ungetc (c, stdin);
|
|
scanf ("%lf", &yylval.NUM);
|
|
return NUM;
|
|
}
|
|
|
|
/* Any other character is a token by itself. */
|
|
return c;
|
|
}
|
|
|
|
/* Called by yyparse on error. */
|
|
void
|
|
yyerror (char const *s)
|
|
{
|
|
fprintf (stderr, "%s\n", s);
|
|
}
|
|
|
|
int
|
|
main (int argc, char const* argv[])
|
|
{
|
|
/* Enable parse traces on option -p. */
|
|
for (int i = 1; i < argc; ++i)
|
|
if (!strcmp(argv[i], "-p"))
|
|
yydebug = 1;
|
|
return yyparse ();
|
|
}
|