mirror of
https://git.savannah.gnu.org/git/bison.git
synced 2026-03-11 21:33:04 +00:00
fc51acddb4
* AUTHORS, ChangeLog-2012, Makefile.am, NEWS, PACKAGING, README, * README-alpha, README-hacking, THANKS, TODO, bootstrap.conf, * build-aux/darwin11.4.0.valgrind, build-aux/local.mk, * build-aux/update-b4-copyright, * build-aux/update-package-copyright-year, cfg.mk, configure.ac, * data/README, data/bison.m4, data/c++-skel.m4, data/c++.m4, * data/c-like.m4, data/c-skel.m4, data/c.m4, data/glr.c, data/glr.cc, * data/java-skel.m4, data/java.m4, data/lalr1.cc, data/lalr1.java, * data/local.mk, data/location.cc, data/stack.hh, data/variant.hh, * data/xslt/bison.xsl, data/xslt/xml2dot.xsl, data/xslt/xml2text.xsl, * data/xslt/xml2xhtml.xsl, data/yacc.c, djgpp/Makefile.maint, * djgpp/README.in, djgpp/config.bat, djgpp/config.sed, * djgpp/config.site, djgpp/config_h.sed, djgpp/djunpack.bat, * djgpp/local.mk, djgpp/subpipe.c, djgpp/subpipe.h, * djgpp/testsuite.sed, doc/bison.texi, doc/local.mk, doc/refcard.tex, * etc/README, etc/bench.pl.in, etc/local.mk, * examples/calc++/calc++.test, examples/calc++/local.mk, * examples/extexi, examples/local.mk, examples/mfcalc/local.mk, * examples/mfcalc/mfcalc.test, examples/rpcalc/local.mk, * examples/rpcalc/rpcalc.test, examples/test, examples/variant.yy, * lib/abitset.c, lib/abitset.h, lib/bbitset.h, lib/bitset.c, * lib/bitset.h, lib/bitset_stats.c, lib/bitset_stats.h, * lib/bitsetv-print.c, lib/bitsetv-print.h, lib/bitsetv.c, * lib/bitsetv.h, lib/ebitset.c, lib/ebitset.h, lib/get-errno.c, * lib/get-errno.h, lib/lbitset.c, lib/lbitset.h, lib/libiberty.h, * lib/local.mk, lib/main.c, lib/timevar.c, lib/timevar.def, * lib/timevar.h, lib/vbitset.c, lib/vbitset.h, lib/yyerror.c, * m4/bison-i18n.m4, m4/c-working.m4, m4/cxx.m4, m4/flex.m4, * m4/timevar.m4, src/AnnotationList.c, src/AnnotationList.h, * src/InadequacyList.c, src/InadequacyList.h, src/LR0.c, src/LR0.h, * src/Sbitset.c, src/Sbitset.h, src/assoc.c, src/assoc.h, * src/closure.c, src/closure.h, src/complain.c, src/complain.h, * src/conflicts.c, src/conflicts.h, src/derives.c, src/derives.h, * src/files.c, src/files.h, src/flex-scanner.h, src/getargs.c, * src/getargs.h, src/gram.c, src/gram.h, src/graphviz.c, * src/graphviz.h, src/ielr.c, src/ielr.h, src/lalr.c, src/lalr.h, * src/local.mk, src/location.c, src/location.h, src/main.c, * src/muscle-tab.c, src/muscle-tab.h, src/named-ref.c, * src/named-ref.h, src/nullable.c, src/nullable.h, src/output.c, * src/output.h, src/parse-gram.c, src/parse-gram.y, src/print-xml.c, * src/print-xml.h, src/print.c, src/print.h, src/print_graph.c, * src/print_graph.h, src/reader.c, src/reader.h, src/reduce.c, * src/reduce.h, src/relation.c, src/relation.h, src/scan-code.h, * src/scan-code.l, src/scan-gram.h, src/scan-gram.l, src/scan-skel.h, * src/scan-skel.l, src/state.c, src/state.h, src/symlist.c, * src/symlist.h, src/symtab.c, src/symtab.h, src/system.h, * src/tables.c, src/tables.h, src/uniqstr.c, src/uniqstr.h, * tests/actions.at, tests/atlocal.in, tests/bison.in, tests/c++.at, * tests/calc.at, tests/conflicts.at, tests/cxx-type.at, * tests/existing.at, tests/glr-regression.at, tests/headers.at, * tests/input.at, tests/java.at, tests/javapush.at, tests/local.at, * tests/local.mk, tests/named-refs.at, tests/output.at, tests/push.at, * tests/reduce.at, tests/regression.at, tests/sets.at, * tests/skeletons.at, tests/synclines.at, tests/testsuite.at, * tests/torture.at, tests/types.at: here.
80 lines
2.9 KiB
Plaintext
80 lines
2.9 KiB
Plaintext
# Sanity test a C compiler.
|
|
|
|
# Copyright (C) 2006, 2009-2014 Free Software Foundation, Inc.
|
|
#
|
|
# This program is free software: you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation, either version 3 of the License, or
|
|
# (at your option) any later version.
|
|
#
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
# Written by Paul Eggert.
|
|
|
|
AC_DEFUN([BISON_TEST_FOR_WORKING_C_COMPILER], [
|
|
AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <limits.h>
|
|
int test_array[CHAR_BIT];]])],
|
|
[],
|
|
[AC_MSG_FAILURE([cannot compile a simple C program])])
|
|
AC_SUBST([BISON_C_WORKS], [:])
|
|
])
|
|
|
|
# BISON_CHECK_WITH_POSIXLY_CORRECT(CODE)
|
|
# --------------------------------------
|
|
# Run the Autoconf CODE with POSIXLY_CORRECT set to 1, and restored to
|
|
# its initial value afterwards.
|
|
AC_DEFUN([BISON_CHECK_WITH_POSIXLY_CORRECT],
|
|
[gl_awk_probe='BEGIN { if ("POSIXLY_CORRECT" in ENVIRON) print "x" }'
|
|
case ${POSIXLY_CORRECT+x}`$AWK "$gl_awk_probe" </dev/null` in
|
|
xx) gl_had_POSIXLY_CORRECT=exported ;;
|
|
x) gl_had_POSIXLY_CORRECT=yes ;;
|
|
*) gl_had_POSIXLY_CORRECT= ;;
|
|
esac
|
|
POSIXLY_CORRECT=1
|
|
export POSIXLY_CORRECT
|
|
$1
|
|
case $gl_had_POSIXLY_CORRECT in
|
|
exported) ;;
|
|
yes) AS_UNSET([POSIXLY_CORRECT]); POSIXLY_CORRECT=1 ;;
|
|
*) AS_UNSET([POSIXLY_CORRECT]) ;;
|
|
esac
|
|
])
|
|
|
|
# BISON_LANG_COMPILER_POSIXLY_CORRECT
|
|
# -----------------------------------
|
|
# Whether the compiler for the current language supports -g in
|
|
# POSIXLY_CORRECT mode. clang-2.9 on OS X does not, because
|
|
# "clang-mp-2.9 -o test -g test.c" launches "/usr/bin/dsymutil test -o
|
|
# test.dSYM" which fails with "error: unable to open executable '-o'".
|
|
#
|
|
# Sets <LANG>_COMPILER_POSIXLY_CORRECT to true/false.
|
|
AC_DEFUN([BISON_LANG_COMPILER_POSIXLY_CORRECT],
|
|
[AC_CACHE_CHECK([whether $_AC_CC supports POSIXLY_CORRECT=1],
|
|
[bison_cv_[]_AC_LANG_ABBREV[]_supports_posixly_correct],
|
|
[BISON_CHECK_WITH_POSIXLY_CORRECT(
|
|
[AC_LINK_IFELSE([AC_LANG_PROGRAM],
|
|
[bison_cv_[]_AC_LANG_ABBREV[]_supports_posixly_correct=yes],
|
|
[bison_cv_[]_AC_LANG_ABBREV[]_supports_posixly_correct=no])])])
|
|
case $bison_cv_[]_AC_LANG_ABBREV[]_supports_posixly_correct in
|
|
yes) AC_SUBST(_AC_LANG_PREFIX[_COMPILER_POSIXLY_CORRECT], [true]) ;;
|
|
no) AC_SUBST(_AC_LANG_PREFIX[_COMPILER_POSIXLY_CORRECT], [false]);;
|
|
esac
|
|
])
|
|
|
|
# BISON_C_COMPILER_POSIXLY_CORRECT
|
|
# --------------------------------
|
|
# Whether the C compiler supports -g in POSIXLY_CORRECT mode.
|
|
AC_DEFUN([BISON_C_COMPILER_POSIXLY_CORRECT],
|
|
[AC_LANG_PUSH([C])
|
|
BISON_LANG_COMPILER_POSIXLY_CORRECT
|
|
AC_LANG_POP([C])
|
|
])
|