mirror of
https://git.savannah.gnu.org/git/bison.git
synced 2026-03-09 12:23:04 +00:00
52ce2a008b
pstate_clear is lacking a prototype. Reported by Ryan https://lists.gnu.org/r/bug-bison/2020-05/msg00101.html Besides, none of the C examples were compiled with the warning flags. * configure.ac (warn_c): Add -Wmissing-prototypes. * data/skeletons/yacc.c (pstate_clear): Make it static. * examples/local.mk (TEST_CFLAGS): New. * examples/c/bistromathic/local.mk, examples/c/calc/local.mk, * examples/c/lexcalc/local.mk, examples/c/mfcalc/local.mk, * examples/c/pushcalc/local.mk, examples/c/reccalc/local.mk, * examples/c/rpcalc/local.mk: Use it. GCC's warn_unused_result is not silenced by a cast to void, so we have to "use" scanf's result. https://gcc.gnu.org/bugzilla/show_bug.cgi?id=25509 https://gcc.gnu.org/bugzilla/show_bug.cgi?id=66425 Flex generated code produces too many warnings, including things such as, with ICC: examples/c/lexcalc/scan.c(1088): error #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem) 2259 YY_INPUT( (&YY_CURRENT_BUFFER_LVALUE->yy_ch_buf[number_to_move]), 2260 ^ 2261 2262 I am tired of trying to fix Flex's output. The project does not seem maintained. We ought to avoid it. So, for the time being, don't try to enable warnings with Flex. * examples/c/bistromathic/parse.y, examples/c/reccalc/scan.l: Fix warnings. * doc/bison.texi: Discard scanf's return value to defeat -Werror=unused-result.
90 lines
2.1 KiB
C
90 lines
2.1 KiB
C
/* Prologue (directives). -*- C -*- */
|
|
|
|
/* Disable Flex features we don't need, to avoid warnings. */
|
|
%option nodefault noinput nounput noyywrap
|
|
|
|
%option reentrant
|
|
|
|
%{
|
|
#include <assert.h>
|
|
#include <limits.h> /* INT_MIN */
|
|
#include <stdlib.h> /* strtol */
|
|
|
|
#include "parse.h"
|
|
%}
|
|
|
|
%x SC_STRING
|
|
|
|
%%
|
|
%{
|
|
// Number of opened parentheses.
|
|
int nesting = 0;
|
|
// A buffer storing the text inside the outer parentheses.
|
|
char *str = NULL;
|
|
// Its allocated size.
|
|
int capacity = 0;
|
|
// Its used size.
|
|
int size = 0;
|
|
#define STR_APPEND() \
|
|
do { \
|
|
if (capacity < size + yyleng + 1) \
|
|
{ \
|
|
do \
|
|
capacity = capacity ? 2 * capacity : 128; \
|
|
while (capacity < size + yyleng + 1); \
|
|
str = realloc (str, (size_t) capacity); \
|
|
} \
|
|
memcpy (str + size, yytext, (size_t) yyleng); \
|
|
size += yyleng; \
|
|
assert (size < capacity); \
|
|
} while (0)
|
|
%}
|
|
|
|
// Rules.
|
|
|
|
"+" return TOK_PLUS;
|
|
"-" return TOK_MINUS;
|
|
"*" return TOK_STAR;
|
|
"/" return TOK_SLASH;
|
|
|
|
"(" nesting += 1; BEGIN SC_STRING;
|
|
|
|
/* Scan an integer. */
|
|
[0-9]+ {
|
|
errno = 0;
|
|
long n = strtol (yytext, NULL, 10);
|
|
if (! (INT_MIN <= n && n <= INT_MAX && errno != ERANGE))
|
|
yyerror (yyscanner, res, "integer is out of range");
|
|
yylval->TOK_NUM = (int) n;
|
|
return TOK_NUM;
|
|
}
|
|
|
|
/* Ignore white spaces. */
|
|
[ \t]+ continue;
|
|
|
|
"\n" return TOK_EOL;
|
|
|
|
. yyerror (yyscanner, res, "syntax error, invalid character: %c", yytext[0]);
|
|
|
|
<SC_STRING>
|
|
{
|
|
"("+ nesting += yyleng; STR_APPEND ();
|
|
")" {
|
|
if (!--nesting)
|
|
{
|
|
BEGIN INITIAL;
|
|
if (str)
|
|
str[size] = 0;
|
|
yylval->TOK_STR = str;
|
|
return TOK_STR;
|
|
}
|
|
else
|
|
STR_APPEND ();
|
|
}
|
|
[^()]+ STR_APPEND ();
|
|
}
|
|
|
|
<<EOF>> return TOK_EOF;
|
|
%%
|
|
/* Epilogue (C code). */
|