Future/iw4_bot_warfare
1
0
Fork 0
mirror of https://github.com/ineedbots/iw4_bot_warfare.git synced 2025-04-22 13:55:43 +00:00
Code Issues Packages Projects Releases Wiki Activity

better bot kicking logic

Browse Source
This commit is contained in:
ineed bots 2023-12-13 12:21:32 -06:00
parent efa67b1421
commit f910ae6054
2 changed files with 93 additions and 1 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
maps/mp/bots/_bot.gsc
View File

@ -956,7 +956,7 @@ addBots_loop()
setDvar( "bots_manage_add", 1 );
else if ( amount > fillAmount && getDvarInt( "bots_manage_fill_kick" ) )
{
tempBot = random( getBotArray() );
tempBot = getBotToKick();
if ( isDefined( tempBot ) )
kick( tempBot getEntityNumber(), "EXE_PLAYERKICKED" );

92
maps/mp/bots/_bot_utility.gsc
View File

@ -745,6 +745,98 @@ notifyAfterDelay( delay, not )
self notify( not );
}
/*
Returns a bot to be kicked
*/
getBotToKick()
{
bots = getBotArray();
if ( !isDefined( bots ) || !isDefined( bots.size ) || bots.size <= 0 || !isArray( bots ) || !isDefined( bots[0] ) )
return undefined;
tokick = undefined;
axis = 0;
allies = 0;
team = getDvar( "bots_team" );
// count teams
for ( i = 0; i < bots.size; i++ )
{
bot = bots[i];
if ( !isDefined( bot ) || !isDefined( bot.team ) )
continue;
if ( bot.team == "allies" )
allies++;
else if ( bot.team == "axis" )
axis++;
else // choose bots that are not on a team first
return bot;
}
// search for a bot on the other team
if ( team == "custom" || team == "axis" )
{
team = "allies";
}
else if ( team == "autoassign" )
{
// get the team with the most bots
team = "allies";
if ( axis > allies )
team = "axis";
}
else
{
team = "axis";
}
// get the bot on this team with lowest skill
for ( i = 0; i < bots.size; i++ )
{
bot = bots[i];
if ( !isDefined( bot ) || !isDefined( bot.team ) )
continue;
if ( bot.team != team )
continue;
if ( !isDefined( bot.pers ) || !isDefined( bot.pers["bots"] ) || !isDefined( bot.pers["bots"]["skill"] ) || !isDefined( bot.pers["bots"]["skill"]["base"] ) )
continue;
if ( isDefined( tokick ) && bot.pers["bots"]["skill"]["base"] > tokick.pers["bots"]["skill"]["base"] )
continue;
tokick = bot;
}
if ( isDefined( tokick ) )
return tokick;
// just kick lowest skill
for ( i = 0; i < bots.size; i++ )
{
bot = bots[i];
if ( !isDefined( bot ) || !isDefined( bot.team ) )
continue;
if ( !isDefined( bot.pers ) || !isDefined( bot.pers["bots"] ) || !isDefined( bot.pers["bots"]["skill"] ) || !isDefined( bot.pers["bots"]["skill"]["base"] ) )
continue;
if ( isDefined( tokick ) && bot.pers["bots"]["skill"]["base"] > tokick.pers["bots"]["skill"]["base"] )
continue;
tokick = bot;
}
return tokick;
}
/*
Gets a player who is host
*/