mirror of
https://github.com/gbdev/rgbds.git
synced 2026-05-08 10:59:36 +00:00
Eldred Habert
6edac50cc4
We can, so let's not ask if we should! More realistically, we can right now so it's nice to mark that we do, but this is subject to be re-evaluated if any later changes conflicts with this. Note also that this only affects the binaries we distribute with our releases! It may very well be possible to compile RGBDS on even older versions of Mac OS X if you have the appropriate compiler setup; we're just not testing it nor offering such binaries ourselves, but third-party packagers are welcome to do so. (Looking at you, TigerBrew! ;)
34 lines
1.8 KiB
CMake
34 lines
1.8 KiB
CMake
# This file is meant to be included at the project level,
|
|
# in order to generate executables compatible with old macOS versions.
|
|
# See our `macos-static` CMake preset for how it's meant to be used.
|
|
|
|
# Note that targeting old enough versions of Mac OS X on recent enough versions of macOS
|
|
# triggers some poorly-tested code paths within Apple's linker, which then crashes.
|
|
# This can be worked around by using LLVM's LLD linker and passing `-fuse-ld=lld` when linking.
|
|
|
|
# The `-mmacosx-version-min=10.4` flag ensures that the binary only uses APIs available on Mac OS X 10.4 Tiger.
|
|
# The `-arch` flags build a "fat binary" that works on both Apple architectures:
|
|
# older Intel x64 Macs and newer ARM "Apple Silicon" ones.
|
|
set(secret_sauce -mmacosx-version-min=10.4 "SHELL:-arch x86_64" "SHELL:-arch arm64") # Avoid `-arch` being dedup'd.
|
|
add_compile_options(${secret_sauce})
|
|
add_link_options(${secret_sauce})
|
|
set(PNG_HARDWARE_OPTIMIZATIONS OFF) # These do not play well with a dual-arch build.
|
|
|
|
# Mac OS X has always provided zlib, so we can safely link dynamically against it.
|
|
# However, libpng is *not* provided by default, so we link it statically, which requires downloading and building it from source.
|
|
set(PNG_SHARED OFF)
|
|
set(PNG_STATIC ON)
|
|
# If libpng is already available (e.g. via Homebrew), we ignore that and still build our own.
|
|
set(FETCHCONTENT_TRY_FIND_PACKAGE_MODE NEVER)
|
|
# But we still want to attempt linking against the system's zlib.
|
|
function(rgbds_provide_dependency method dep_name)
|
|
if(dep_name STREQUAL "ZLIB")
|
|
find_package(ZLIB)
|
|
if(ZLIB_FOUND)
|
|
FetchContent_SetPopulated(ZLIB)
|
|
endif()
|
|
endif()
|
|
endfunction(rgbds_provide_dependency)
|
|
cmake_language(SET_DEPENDENCY_PROVIDER rgbds_provide_dependency
|
|
SUPPORTED_METHODS FETCHCONTENT_MAKEAVAILABLE_SERIAL)
|