mirror of
https://git.savannah.gnu.org/git/bison.git
synced 2026-03-09 20:33:03 +00:00
c1d19e10c3
* data/bison.m4 (b4_percent_define_flag_if): Don't treat 0 as false. Complain if the value does not match empty, "true" or "false". * data/c++.m4: Adjust default definitions of %define variables. * data/java.m4: Adjust default definitions of %define variables. * doc/bison.texinfo (Decl Summary): Adjust the %define entry according to above behavior. * tests/input.at (Boolean %define variables): Test new behavior.
269 lines
7.3 KiB
Plaintext
269 lines
7.3 KiB
Plaintext
-*- Autoconf -*-
|
|
|
|
# Java language support for Bison
|
|
|
|
# Copyright (C) 2007 Free Software Foundation, Inc.
|
|
|
|
# This program is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 2 of the License, or
|
|
# (at your option) any later version.
|
|
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program; if not, write to the Free Software
|
|
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
|
|
# 02110-1301 USA
|
|
|
|
|
|
# b4_comment(TEXT)
|
|
# ----------------
|
|
m4_define([b4_comment], [/* m4_bpatsubst([$1], [
|
|
], [
|
|
]) */])
|
|
|
|
|
|
# b4_flag_value(BOOLEAN-FLAG)
|
|
# ---------------------------
|
|
m4_define([b4_flag_value], [b4_flag_if([$1], [true], [false])])
|
|
|
|
|
|
# b4_public_if(TRUE, FALSE)
|
|
# -------------------------
|
|
b4_percent_define_default([[public]], [[false]])
|
|
m4_define([b4_public_if],
|
|
[b4_percent_define_flag_if([public], [$1], [$2])])
|
|
|
|
# b4_single_class_if(TRUE, FALSE)
|
|
# -------------------------------
|
|
b4_percent_define_default([[single_class]], [[false]])
|
|
m4_define([b4_single_class_if],
|
|
[b4_percent_define_flag_if([single_class], [$1], [$2])])
|
|
|
|
|
|
# b4_abstract_if(TRUE, FALSE)
|
|
# ---------------------------
|
|
m4_define([b4_abstract_if],
|
|
[b4_pure_if([$2], [b4_single_class_if([$2], [$1])])])
|
|
|
|
|
|
# b4_identification
|
|
# -----------------
|
|
m4_define([b4_identification],
|
|
[/** Always <tt>true</tt>, identifies Bison output. */
|
|
public static final boolean bison = true;
|
|
|
|
/** Version number for the Bison executable that generated this parser. */
|
|
public static final String bisonVersion = "b4_version";
|
|
|
|
/** Name of the skeleton that generated this parser. */
|
|
public static final String bisonSkeleton = b4_skeleton;
|
|
])
|
|
|
|
|
|
## ------------ ##
|
|
## Data types. ##
|
|
## ------------ ##
|
|
|
|
# b4_int_type(MIN, MAX)
|
|
# ---------------------
|
|
# Return the smallest int type able to handle numbers ranging from
|
|
# MIN to MAX (included).
|
|
m4_define([b4_int_type],
|
|
[m4_if(b4_ints_in($@, [-128], [127]), [1], [byte],
|
|
b4_ints_in($@, [-32768], [32767]), [1], [short],
|
|
[int])])
|
|
|
|
# b4_int_type_for(NAME)
|
|
# ---------------------
|
|
# Return the smallest int type able to handle numbers ranging from
|
|
# `NAME_min' to `NAME_max' (included).
|
|
m4_define([b4_int_type_for],
|
|
[b4_int_type($1_min, $1_max)])
|
|
|
|
# b4_null
|
|
# -------
|
|
m4_define([b4_null], [null])
|
|
|
|
|
|
## ------------------------- ##
|
|
## Assigning token numbers. ##
|
|
## ------------------------- ##
|
|
|
|
# b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
|
|
# ---------------------------------------
|
|
# Output the definition of this token as an enum.
|
|
m4_define([b4_token_enum],
|
|
[ /** Token number, to be returned by the scanner. */
|
|
public static final int $1 = $2;
|
|
])
|
|
|
|
|
|
# b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
|
|
# -----------------------------------------------------
|
|
# Output the definition of the tokens (if there are) as enums.
|
|
m4_define([b4_token_enums],
|
|
[m4_if([$@], [[]], [],
|
|
[/* Tokens. */
|
|
m4_map([b4_token_enum], [$@])])
|
|
])
|
|
|
|
# b4-case(ID, CODE)
|
|
# -----------------
|
|
# We need to fool Java's stupid unreachable code detection.
|
|
m4_define([b4_case], [ case $1:
|
|
if (yyn == $1)
|
|
$2;
|
|
break;
|
|
])
|
|
|
|
|
|
## ---------------- ##
|
|
## Default values. ##
|
|
## ---------------- ##
|
|
|
|
m4_define([b4_union_name], [b4_percent_define_get([[union_name]])])
|
|
b4_percent_define_default([[union_name]], [[Object]])])
|
|
|
|
m4_define_default([[b4_prefix]], [[YY]])])
|
|
b4_percent_define_default([[parser_class_name]], [b4_prefix[]Parser])])
|
|
m4_define([b4_parser_class_name], [b4_percent_define_get([[parser_class_name]])])
|
|
|
|
b4_percent_define_default([[lex_throws]], [[java.io.IOException]])])
|
|
m4_define([b4_lex_throws], [b4_percent_define_get([[lex_throws]])])
|
|
|
|
b4_percent_define_default([[throws]], [b4_lex_throws])])
|
|
m4_define([b4_throws], [b4_percent_define_get([[throws]])])
|
|
|
|
b4_percent_define_default([[location_type]], [Location])])
|
|
m4_define([b4_location_type], [b4_percent_define_get([[location_type]])])
|
|
|
|
b4_percent_define_default([[position_type]], [Position])])
|
|
m4_define([b4_position_type], [b4_percent_define_get([[position_type]])])
|
|
|
|
|
|
## ----------------- ##
|
|
## Semantic Values. ##
|
|
## ----------------- ##
|
|
|
|
|
|
# b4_lhs_value([TYPE])
|
|
# --------------------
|
|
# Expansion of $<TYPE>$.
|
|
m4_define([b4_lhs_value], [yyval])
|
|
|
|
|
|
# b4_rhs_value(RULE-LENGTH, NUM, [TYPE])
|
|
# --------------------------------------
|
|
# Expansion of $<TYPE>NUM, where the current rule has RULE-LENGTH
|
|
# symbols on RHS.
|
|
#
|
|
# In this simple implementation, %token and %type have class names
|
|
# between the angle brackets.
|
|
m4_define([b4_rhs_value],
|
|
[(m4_ifval([$3], [($3)])[](yystack.valueAt ($1-($2))))])
|
|
|
|
# b4_lhs_location()
|
|
# -----------------
|
|
# Expansion of @$.
|
|
m4_define([b4_lhs_location],
|
|
[(yyloc)])
|
|
|
|
|
|
# b4_rhs_location(RULE-LENGTH, NUM)
|
|
# ---------------------------------
|
|
# Expansion of @NUM, where the current rule has RULE-LENGTH symbols
|
|
# on RHS.
|
|
m4_define([b4_rhs_location],
|
|
[yystack.locationAt ($1-($2))])
|
|
|
|
|
|
# b4_lex_param
|
|
# b4_parse_param
|
|
# --------------
|
|
# If defined, b4_lex_param arrives double quoted, but below we prefer
|
|
# it to be single quoted. Same for b4_parse_param.
|
|
|
|
# TODO: should be in bison.m4
|
|
m4_define_default([b4_lex_param], [[]]))
|
|
m4_define([b4_lex_param], b4_lex_param))
|
|
m4_define([b4_parse_param], b4_parse_param))
|
|
|
|
# b4_lex_param_decl
|
|
# -------------------
|
|
# Extra formal arguments of the constructor.
|
|
m4_define([b4_lex_param_decl],
|
|
[m4_ifset([b4_lex_param],
|
|
[b4_remove_comma([$1],
|
|
[m4_map([b4_lex_param_decl_1], [b4_lex_param])])],
|
|
[$1])])
|
|
|
|
m4_define([b4_lex_param_decl_1], [, $1])
|
|
m4_define([b4_remove_comma], [m4_ifval([$1], [$1, ], [])m4_cdr([m4_cdr($@)])])
|
|
|
|
|
|
|
|
# b4_lex_param_call
|
|
# -------------------
|
|
# Extra initialisations of the constructor.
|
|
m4_define([b4_lex_param_call],
|
|
[m4_ifset([b4_lex_param],
|
|
[b4_remove_comma([$1],
|
|
[b4_lex_param_calls(b4_lex_param)])],
|
|
[$1])])
|
|
m4_define([b4_lex_param_calls],
|
|
[m4_map([b4_lex_param_call_1], [$@])])
|
|
m4_define([b4_lex_param_call_1], [, $2])
|
|
|
|
|
|
|
|
# b4_parse_param_decl
|
|
# -------------------
|
|
# Extra formal arguments of the constructor.
|
|
m4_define([b4_parse_param_decl],
|
|
[m4_ifset([b4_parse_param],
|
|
[b4_remove_comma([$1],
|
|
[m4_map([b4_parse_param_decl_1],
|
|
[b4_parse_param])])],
|
|
[$1])])
|
|
|
|
m4_define([b4_parse_param_decl_1], [, $1])
|
|
|
|
|
|
|
|
# b4_parse_param_cons
|
|
# -------------------
|
|
# Extra initialisations of the constructor.
|
|
m4_define([b4_parse_param_cons],
|
|
[m4_ifset([b4_parse_param],
|
|
[b4_constructor_calls(b4_parse_param)])])
|
|
m4_define([b4_constructor_calls],
|
|
[m4_map([b4_constructor_call], [$@])])
|
|
m4_define([b4_constructor_call],
|
|
[this.$2 = $2;
|
|
])
|
|
|
|
# b4_parse_param_vars
|
|
# -------------------
|
|
# Extra instance variables.
|
|
m4_define([b4_parse_param_vars],
|
|
[m4_ifset([b4_parse_param],
|
|
[
|
|
/* User arguments. */
|
|
b4_var_decls(b4_parse_param)])])
|
|
m4_define([b4_var_decls],
|
|
[m4_map_sep([b4_var_decl], [
|
|
], [$@])])
|
|
m4_define([b4_var_decl],
|
|
[ protected final $1;])
|
|
|
|
# b4_maybe_throws(THROWS)
|
|
# -----------------------
|
|
# Expand to either an empty string or "throws THROWS".
|
|
m4_define([b4_maybe_throws],
|
|
[m4_ifval([$1], [throws $1])])
|